How to open a UFL file - Driving Simulator 2009

gonastra · **Joined:** 15 Mar 2010 14:21 **Posts:** 9

Hello, i need some help because i want to open (for modding purposes) a file called "data 1.12.UFL" from the Driving Simulator 2009 game. (see: http://www.astragon.com/)
Unfortunately the file is too big (800mb) to upload an example. I supose is a kind of ZIP and for that reason i try to change the extension an open with a simple unzipper, but as you can imagine, it doesn??t work!

Does anyone can help me?

Thanks in advance.

aluigi · **Posted:** 15 Mar 2010 23:23

a not so simple file format, anyway job done :)

Code:

# Driving Simulator 2009
# script for QuickBMS http://aluigi.org/papers.htm#quickbms

idstring "LiArFi\n"
get DUMMY long
get DUMMY byte
get INFO_OFF long
goto INFO_OFF

set PATH string ""
callfunction EXTRACT

startfunction EXTRACT
    get PREV_OFF long
    get NEXT_OFF long
    get ENTRIES long
    set ENTRIES_MAIN long ENTRIES
    for i = 0 < ENTRIES_MAIN
        get NAMESZ byte
        if PREV_OFF >= INFO_OFF
            get DUMMY byte
        endif
        math NAMESZ += 1
        getdstring NAME NAMESZ
        if PREV_OFF >= INFO_OFF
            set PATH string NAME
            get TMP byte
            math TMP += 1
            getdstring TMP TMP
            string NAME += /
            string NAME += TMP
        else
            set TMP string NAME
            set NAME string PATH
            string NAME += /
            string NAME += TMP
        endif
        get PREV_OFF long
        if PREV_OFF < 0x20
            get NEXT_OFF long
            get ENTRIES long
            if NEXT_OFF != 0
                savepos TMP
                goto NEXT_OFF
                callfunction EXTRACT
                goto TMP
            endif
        else
            get OFFSET long
            get DUMMY long
            get SIZE long
            get DUMMY long
            get CRC long
            get DUMMY long
            log NAME OFFSET SIZE
        endif
    next i
endfunction

gonastra · **Joined:** 15 Mar 2010 14:21 **Posts:** 9

Thanks Luigi, i will test!

gonastra · **Joined:** 15 Mar 2010 14:21 **Posts:** 9

It works perfect. Thanks.

I have another dude and maybe you can help me: I have a .mft file (in the same game) it seems to be an image (i searched google without luck, sorry). I cant open to edit that .mft file, any idea?

Here??s an example: http://rapidshare.com/files/367127873/m ... e.zip.html

Thanks in advance, again!

aluigi · **Posted:** 24 Mar 2010 11:15

no idea, judging the name isn't possible that it's the project file of something nvidia related?

gonastra · **Joined:** 15 Mar 2010 14:21 **Posts:** 9

Right! It??s a DX image... looking with a hexaeditor y saw something about DX1, DX3 or DX5, i try to change the extension to DDS format without success. Maybe there??s a way to convert this "mft" format to another and again to "mft"... I can??t find on internet any editor or photoshop plugin for this files.

Luigi Auriemma

How to open a UFL file - Driving Simulator 2009